Prerequisites: Derivatives of trigonometric functions, higher order derivatives.

Goal: To investigate properties of circular (harmonic) motion. To show that one component of harmonic motion satisfies Hooke's Law.

Today we will be investigating uniform-speed circular motion. After starting Maple, click File → New → Worksheet Mode to prepare Maple to accept commands. Then copy and paste the following code into your Maple worksheet. The color is only for your own reference; you may want to edit the purple characters, but probably not the red.

restart: with(plots):
R := 1:               # radius of circle
ω := 2:               # radians/(time unit)
x := t -> R*cos(ω*t): # x-component of motion
y := t -> R*sin(ω*t): # y-component of motion

circle := plot([R*cos(t),R*sin(t),t=0..2*Pi],color=gray, thickness=2):
shadow := animate([x(t)+R/100*cos(k),y(t)+R/100*sin(k),
          k=0..2*Pi],t=Pi/24..2*Pi,tickmarks=[[-R,R],[-R,R]],
          color=blue,frames=48):
motion := animate([x(t)+R/100*cos(k),0+R/100*sin(k),k=0..2*Pi],
          t=Pi/24..2*Pi,color=red,frames=48,thickness=5):
display(circle,shadow,motion,scaling=constrained);

Note: The character "ω" is a greek letter omega, not the letter "w." It is used to represent angular velocity in physics.

1. Try various different values for R such as 2, -2, 1.5, and 3. What changes about the motion? In particular, how is the motion determined by the value of R?
2. Try various different values for ω, such as 1, -1, 1/2, and 2. What changes about the motion? In particular, how is the motion determined by the value of ω?
3. The center of the blue dot has x-component x(t)=R cos(ωt), and y-component y(t)=R sin(ωt), where the variable t represents time. What are the x- and y-components of the center of the red dot? [You do not need to read the Maple code to answer this question.]
4. Cut and paste the following code into Maple.

   position := plot(R*cos(ω*t),t=0..2*Pi,tickmarks=[[0,2*Pi],
               [-R,R]],scaling=constrained,color=blue):
   display(position);

   The graph it plots [y=R cos(ωt)] represents something about the red dot in the previous animation: the horizontal axis represents time (t), and the vertical axis represents what?
5. Find the velocity of the red dot at time "t". [Hint: since the y-component of the red dot's position is always 0, the position function is the x-component. You already know how to find velocity if given a position function.]
6. Cut and paste the following code into Maple, replacing the underscore with the velocity function from question 5. (You may need to cut and paste a character ω from somewhere else for your function.)

   velocity := plot(________,t=0..2*Pi,tickmarks=[[0,2*Pi],
               [-R*ω,R*ω]],scaling=constrained,color=red):
   display(velocity);

   The graph it plots represents something about the red dot in a previous animation: the horizontal axis represents time (t), and the vertical axis represents what? What does it mean when the graph is negative?
7. Find the acceleration of the red dot at time "t".
8. Cut and paste the following code into Maple, replacing the underscore with the acceleration function from question 7.

   accelera := plot(________,t=0..2*Pi,tickmarks=[[0,2*Pi],
               [-R*ω^2,R*ω^2]],scaling=constrained,color=green):
   display(accelera);

   The graph it plots represents something about the red dot in a previous animation; the horizontal axis represents time (t), and the vertical axis represents what? What does it mean when the graph is negative?
9. Lastly, cut and paste the following code into Maple.

   display(accelera, velocity, position);

   It shows all three of the previous graphs at once. Although it can be useful to see the relationships between the graphs, a physics professor would cringe to see them all together; the horizontal axis represents time, but the vertical axis must simultaneously represent three different things. What are they?
10. Hooke's Law says that the force of a spring (pushing or pulling on a mass) is proportional to the displacement (signed distance) x the spring has been pushed or pulled from equilibrium, i.e.: F=-kx. Newton's 2^nd law of motion says that the force acting on an object is equal to the product of its mass and its acceleration, i.e., F=ma. Show that the shadow's motion satisfies Hooke's Law for a mass on a spring by showing that these two equations are compatible, i.e., ma=-kx.[Hint: What is x in our case? What is a? If the two equations are compatible, you should be able to solve for ω, a constant, in terms of the two constants k and m.]